Can this regex be written better?

[travs69]

use strict;
my $val = 'Rpc:0xf98103';
my $test = join('=',map(hex,$val =~ /(\w{2})(\w{2})(\w{2})$/));
print "$test\n";

I was thinking there would have to be a way to say do 3 (\w{2})'s with out hand putting them in.

Thanks!

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

Travis - Those who say it cannot be done are usually interrupted by someone else doing it; Give the wrong symptoms, get the wrong solutions;

 

[MillerH]

Hey travs,

You're not the first person to try to do something like this, and the quick answer is that no, it's not possible.

Each capture block is given a number when the regex is initially parsed. If you include a capture within a multiplier, only the last capture will be assigned to the variable.

/(\w{2}){3}$/ for example, will only capture '03' since it's the last one in the loop.

There are of course ways around that, even with a one liner. But your solution is going to be the most readable, although stylistically I'd change it some:

my $test = join '=', map {hex} $val =~ /(\w{2})(\w{2})(\w{2})$/;

- Miller

 

[MillerH]

If the length of the hex string is variable, this is how I would do the translation.

Note, I included some fake data:

use strict;
use warnings;

while (<DATA>) {
	chomp;
	my ($src, $goal) = split;

	my ($hex) = $src =~ /([a-f0-9]*)$/;
	$hex = '0' . $hex if length($hex) % 2;
	my $result = join '=', map {hex} $hex =~ /(..)/g;
	
	printf "%-16s %-12s %-12s\n", $src, $goal, $result;
}

__DATA__
Fake:0xf98103    249=129=3
Fake:0x17        23
Fake:0xa0b0c0d   10=11=12=13
Fake:0x10203040  16=32=48=64
Fake:0xffff      255=255
Fake:0xfff       15=255