Batch File Back Up

[Keyboy]

Greetings,

I am running W7 Home Premium on a Dell Laptop. I have used the following bat file to back up my computer for years, however, when I tried to run it today (as a user and administrator) I got the errors below.

@Echo Off
Echo.
If exist E:\ (Echo. External USB HD ready for BackUp) else (Echo. No External USB HD detected & Goto :EOF)
Echo.
pause
Echo.
Set ToDay=%Date:~-4,4%-%Date:~-10,2%-%Date:~-7,2%
XCopy "C:\Users\%UserName%\Documents" E:\Ray_BackUp_%ToDay%\"My Documents" /I /E /S /V
XCopy "C:\Users\%UserName%\Favorites" E:\Ray_BackUp_%ToDay%\Favorites /I /E /S /V
XCopy "C:\Users\%UserName%\Desktop\*.bat" E:\Ray_BackUp_%ToDay%\Desktop /I /E /S /V
XCopy "C:\Users\%UserName%\AppData\Local\Microsoft\Windows Mail" E:\Ray_BackUp_%ToDay%\"Windows Mail" /I /E /S /V
XCopy "C:\Xnews_test 2006.06.28\*.*" E:\Ray_BackUp_%ToDay%\xNEWS /I /E /S /V
Set ToDay=
::END_OF_BATCH
Echo.
Echo.
Echo. All Done
pause

I apologize that the long lines wrapped. There are no spaces between the wrapped lines.

Here are the errors:

Invalid Switch - /\"My Documents"
Invalid Switch - /\Favorites
Invalid Switch - /\Desktop
Invalid Switch - /\"Windows Mail"
Invalid Switch - /\xNews

Any idea how to get this file to run?

Thanks for your help!

 

[flyboytim]

Your old system, I guess it was XP, stored user files on paths differently to those now in Vista and Win 7.

Much of this is due to the use of symbolic links called Junctions instead of old-fashioned directories -

http://technet.microsoft.com/en-us/magazine/ee851567.aspx

http://ipggi.wordpress.com/2009/09/07/windows-file-junctions-symbolic-links-and-hard-links/

You will need to work out the paths to the various directories without falling foul of some non-traversable link, and put those in the batch file.

 

[Keyboy]

Hi flyboytim,

This batch file was written for XP, however, for over a year it worked on my W7 laptop. I have installed all the updates so maybe a recent one of them changed something?

I will read through your links and see if I can make changes.

Thanks for your help!

 

[TonHu]

Check the value of ToDay. It probably contains a space, as January only has 1 digit in it's numeric value. Quote just the entire destination path, not only the parts that you think contain spaces, something like:

XCopy "C:\Users\%UserName%\Documents" "E:\Ray_BackUp_%ToDay%\My Documents" /I /E /S /V

 

[flyboytim]

I Googled xcopy windows 7 and the following was at the top of the heap:

See this thread:

http://social.technet.microsoft.com.../thread/beebadc6-bcff-4a38-b26a-55fe0d0eb7a5/

It recommends using the "Robocopy" command in place of the legacy DOS XCOPY command.

Let us know what transpires.

 

[Nelviticus]

You should be able to get around the errors by wrapping the whole of the destination parameter in quotes like you've done with the source paramaters, i.e.:

XCopy "C:\Users\%UserName%\Documents" "E:\Ray_BackUp_%ToDay%\My Documents" /I /E /S /V
XCopy "C:\Users\%UserName%\Favorites" "E:\Ray_BackUp_%ToDay%\Favorites" /I /E /S /V
XCopy "C:\Users\%UserName%\Desktop\*.bat" "E:\Ray_BackUp_%ToDay%\Desktop" /I /E /S /V
XCopy "C:\Users\%UserName%\AppData\Local\Microsoft\Windows Mail" "E:\Ray_BackUp_%ToDay%\Windows Mail" /I /E /S /V
XCopy "C:\Xnews_test 2006.06.28\*.*" "E:\Ray_BackUp_%ToDay%\xNEWS" /I /E /S /V

Nelviticus

 

[Nelviticus]

Actually you can shorten those a bit by using some different environment variables:

XCopy "%UserProfile%\Documents" "E:\Ray_BackUp_%ToDay%\My Documents" /I /E /S /V
XCopy "%UserProfile%\Favorites" "E:\Ray_BackUp_%ToDay%\Favorites" /I /E /S /V
XCopy "%UserProfile%\Desktop\*.bat" "E:\Ray_BackUp_%ToDay%\Desktop" /I /E /S /V
XCopy "%LocalAppData%\Microsoft\Windows Mail" "E:\Ray_BackUp_%ToDay%\Windows Mail" /I /E /S /V

Then it'll still work if you ever move your user profile.

Nelviticus

 

[Keyboy]

Thanks to all!

I tried it all and same thing. I believe it must be some sort of new security thing. I gave up and moved to robocopy.

 

[TonHu]

Check your quotes again, you must have missed one.