Auto Faxing Reports

[Trudye]

Hi guys, I have a problem. We are producing a report that needs to be faxed using MS Fax.

The report based on the center needs to be faxed to different sites. We have a lookup table that contains the center# and corresponding fax number. But how do we automate this process?

Does anyone have any ideas?

Thanks so much
Trudye

 

[WhiteZiggy]

You can use MSFAX is you wish. You just need to set up in outlook (thats my email client) add a new email called Fax Mail Transport. It is in the list you chose from. Then in the modules section place this code...
'********************************************************************************************
' This function will walk through the Customers table and fax the Invoices report which
' is filtered by the CustomerId field using MSFax through Access SendObject.
'
' This function assumes the report rptMSFaxInvoices has the default printer set to MSFax
' and the MSFax driver is installed correctly.
' *******************************************************************************************
'
Function MSFaxInvoices()

'********************************************************************************************
' Diming all variables
'********************************************************************************************

Dim dbsNorthwind As Database
Dim rstCustomers As Recordset

'********************************************************************************************
' Setting database and recordset variables
'********************************************************************************************

Set dbsNorthwind = CurrentDb()
Set rstCustomers = dbsNorthwind.OpenRecordset("Customers", dbOpenDynaset) ' Set Recordset to Customers table

'********************************************************************************************
' Walking through the Customers recordset until end of file, setting the global variable
' strInvoicesWhere to the current where and using SendObject passing
' customers fax number and report name.
'********************************************************************************************

If MsgBox("Do you want to fax invoices" & Chr(13) & "to all customers using MSFax?", 4) = 6 Then
With rstCustomers
Do Until .EOF
strInvoiceWhere = "[customerid] = '" & ![CustomerID] & "'" ' sets global strInvoiceWhere
DoCmd.SendObject acReport, "rptMSFaxInvoice", acFormatRTF, "[fax:" & ![Fax] & "]", , , , , False ' Runs Report to MSFax
.MoveNext ' Move to next record in Recordset
Loop
End With
End If


End Function

See where the sendobject uses "Fax:" and then adds the number from the table. This works great. Outlook sees the "Fax" then uses the Fax client and your phone line to fax the items.

Hope This Helps,
Jeremy
WZ

 

[Trudye]

Thanks so much Jeremy I'll give it a shot.

Trudye