Appending the sent date/time to a received email attachment

[EliseFreedman]

Hi There

I am using the following code to go through all emails in an inbox and save the attachments to a folder.

Sub SaveEmailAttachmentsToFolder(OutlookFolderInInbox As String, _
                                 ExtString As String, DestFolder As String)
    Dim ns As Namespace
    Dim Inbox As MAPIFolder
    Dim SubFolder As MAPIFolder
    Dim Item As Object
    Dim Atmt As Attachment
    Dim FileName As String
    Dim MyDocPath As String
    Dim i As Integer
    Dim wsh As Object
    Dim fs As Object

    On Error GoTo ThisMacro_err

    Set ns = GetNamespace("MAPI")
       Set Inbox = ns.GetDefaultFolder(olFolderInbox)
    Set SubFolder = Inbox.Folders(OutlookFolderInInbox)

    i = 0
    ' Check subfolder for messages and exit of none found
    If SubFolder.Items.Count = 0 Then
        MsgBox "There are no messages in this folder : " & OutlookFolderInInbox, _
               vbInformation, "Nothing Found"
        Set SubFolder = Nothing
        Set Inbox = Nothing
        Set ns = Nothing
        Exit Sub
    End If

    'Create DestFolder if DestFolder = ""
    If DestFolder = "" Then
        Set wsh = CreateObject("WScript.Shell")
        Set fs = CreateObject("Scripting.FileSystemObject")
        MyDocPath = wsh.SpecialFolders.Item("mydocuments")
        DestFolder = MyDocPath & "\" & Format(Now, "dd-mmm-yyyy hh-mm-ss")
        If Not fs.FolderExists(DestFolder) Then
            fs.CreateFolder DestFolder
        End If
    End If

    If Right(DestFolder, 1) <> "\" Then
        DestFolder = DestFolder & "\"
    End If

    ' Check each message for attachments and extensions
    For Each Item In SubFolder.Items
        For Each Atmt In Item.Attachments
            If LCase(Right(Atmt.FileName, Len(ExtString))) = LCase(ExtString) Then
                FileName = DestFolder & " " & Atmt.FileName
                Atmt.SaveAsFile FileName
                i = i + 1
            End If
        Next Atmt
     


    Next Item

    ' Show this message when Finished
    If i > 0 Then
        MsgBox "You can find the files here : " _
             & DestFolder, vbInformation, "Finished!"
    Else
        MsgBox "No attached files in your mail.", vbInformation, "Finished!"
    End If

    ' Clear memory
ThisMacro_exit:
    Set SubFolder = Nothing
    Set Inbox = Nothing
    Set ns = Nothing
    Set fs = Nothing
    Set wsh = Nothing
    Exit Sub
    
ThisMacro_err:
    MsgBox "An unexpected error has occurred." _
         & vbCrLf & "Please note and report the following information." _
         & vbCrLf & "Macro Name: SaveEmailAttachmentsToFolder" _
         & vbCrLf & "Error Number: " & Err.Number _
         & vbCrLf & "Error Description: " & Err.Description _
         , vbCritical, "Error!"
    Resume ThisMacro_exit
End Sub

The attachments are output from an adobe form which have been sent using the submit button. The problem that I have is that all the attachments have the same name. I was wanting the vba to go through the attachments and alter the filenames to append the received date/time to them so that the attachments would be saved as unique files rather than someone having to manually go through the emails and save the attachments with a unique name. Is this possible and if so how would I do it? I cant use the senders name as a unique identified because all the emails are initially sent to my inbox and then forwarded to the 2nd inbox to allow the use of an email acknowledgement when the form is received.

I suspect I have to change the line FileName = DestFolder & " " & Atmt.FileName but not sure what to change it to

 

[EliseFreedman]

Solved. Just found the answer

 

[SkipVought]

hi,

FileName = DestFolder & " " & Atmt.FileName & "_" & format(now, "yymmddhhnnss")

or

i = i + 1
FileName = DestFolder & " " & Atmt.FileName & "_" & format(i, "00")

Skip,

_{Just traded in my old subtlety...
for a NUANCE!}

 

[PHV]

FileName = DestFolder & Format(Item.ReceivedTime, "yyyymmddhhnnss") & Atmt.FileName

Hope This Helps, PH.
FAQ219-2884
FAQ181-2886