Any examples of pieced bodies?

[WhiteTiger]

I have an idea for an intro to my page, but I was wondering if anyone knew of any place which had almost the same thing going on.

What I want to do, is take a picture of me running. I want to cut all the sections of my body, and animate them by moving the pieces. (the objects would be pictures from tip of fingers to wrist, wrist to elbow, elbow to shoulder)

Does anyone know where someone else has done this?...I want to see if anyone has done it before, and if I really like the look of it. Regards,
Anthny

 

[wangbar]

Here's a simple version:

http://wangbar.co.uk/f1/austria.html

- move your mouse over the guy's arm when he eventually appears (only funny if you're into motor racing)

Here's a complex one:

http://www.vectorlounge.com/04_amsterdam/jam/wireframe.html

- and your guess is as good as mine as to how they worked out the math behind the inverse kinematics in Flash. Slainte

http://www.wangbar.co.uk

 

[WhiteTiger]

IMPRESSIVE
Do you have any tips on getting ends of limbs to stay connected when doing an animation?...or how to go about making this animation?

Remember, I'm not as good in math as you aparrently are.
Basically what I'm doing is just a few skits as intros, etc. Regards,
Anthny

 

[wangbar]

This is the actionscript I used for the arm (I've removed some other stuff like the strings etc that wasn't relevant).

Basically you're concentrating on two the joints between limbs - they're the important bits. They have to be kept the right distance apart so that the limbs don't stretch out of shape. Where it says "bit of trig" that's where that's being calculated - the elbow and shoulder always stay the same distance apart.

The rest is calculating the angles between the limbs then using the Math function atan2 to work out what rotation to apply to the limbs to make them line up with those angles.

Anything named "Hookes" is applying Hooke's Law which governs elasticity and that's creating the bouncing effects.

Anyway maybe you can cut and paste some of this or it might give you some ideas, most of it is just using simple arithmetic to work out distances.

onClipEvent (load) {
	_root.limbLength = 85;
	speed = 2;
	xHome = _root.wrist._x;
	yHome = _root.wrist._y;
	_root.wrist._x = xHome+30;
	_root.wrist._y = yHome-20;


	function resetHookes() {
		targetX = xHome;
		targetY = yHome;
		posX = _root.wrist._x;
		posY = _root.wrist._y;
		accelX = 0;
		accelY = 0;
		velocX = 0;
		velocY = 0;
		k = .3;
		m = 1;
		friction = .9;
	}

	function doHookes() {
		accelX = -(k/m)*(posX-targetX);
		accelY = -(k/m)*(posY-targetY);
		velocX += accelX;
		velocY += accelY;
		velocX *= friction;
		velocY *= friction;
		posX += velocX;
		_root.wrist._x = posX;
		posY += velocY;
		_root.wrist._y = posY;
	}

	function moveArm() {
		forearmDeltaX = _root.wrist._x-_root.elbow._x;
		forearmDeltaY = _root.wrist._y-_root.elbow._y;
		upperarmDeltaX = _root.elbow._x-_root.shoulder._x;
		upperarmDeltaY = _root.elbow._y-_root.shoulder._y;
		_root.forearm._rotation = Math.atan2(forearmDeltaY, forearmDeltaX)/Math.PI*180;
		_root.upperarm._rotation = Math.atan2(upperarmDeltaY, upperarmDeltaX)/Math.PI*180;
		_root.forearm._x = _root.wrist._x-forearmDeltaX;
		_root.forearm._y = _root.wrist._y-forearmDeltaY;
		_root.upperarm._x = _root.elbow._x-upperarmDeltaX;
		_root.upperarm._y = _root.elbow._y-upperarmDeltaY;
	}
}

onClipEvent (enterFrame) {
	xDiff = (_root.shoulder._x-_root._xmouse);
	yDiff = (_root.shoulder._y-_root._ymouse);
	distance = Math.sqrt(xDiff*xDiff+yDiff*yDiff);
	if (distance<_root.limbLength*2 && Math.abs(yDiff)<25 && _root._xmouse<(_root.shoulder._x-30)) {
		_root.wrist._x += (_root._xmouse-_root.wrist._x)/speed;
		_root.wrist._y += (_root._ymouse-_root.wrist._y)/speed;
		//reset hooke's
		resetHookes();
	} else {
		//doHookes
		doHookes();
	}
	distX = ((_parent.shoulder._x-_parent.wrist._x)/2);
	_parent.elbow._x = _parent.wrist._x+distX;
	bitOfTrig = Math.sqrt((_root.limbLength*_root.limbLength)-(distX*distX));
	_parent.elbow._y = _parent.shoulder._y+bitOfTrig;
	moveArm();
	
}[code] Slainte

[URL unfurl="true"]http://www.wangbar.co.uk[/URL]