After hours on call - automated change of destination 2

[Tman45]

Hey guys/gals.

I was thinking about this function with script date checking. Basically, we want calls to change destination based on a particualr calendar week. Almost every week we have a new On Call person and that also varies by which department the caller chooses.

We have a CS1000E w/CC6 where we are going to want to write an 'automated' script to change our On Call destination. We have a group of 6-12 persons that will accept that calls that are broken down into 5 different categories (based on needed support). Do you have a best practice for providing a more automated approach that can also accept human intervention? Sometimes the normal On Call person has to rotate their schedule with someone else.
So, if a call would normally go to Option 1 - 123-456-7890 can we easily intervene and make it go to option 2 - 234-789-1023
Just curious if someone has a neat way to do this function.
The calls would initially land via our ACD and our main Help Desk skillset would field the call and provide the after hours menu with the options of On Call persons to reach. Thanks in advance!

 

[Utreg]

There are serveral ways to setup something like that.
It can be done via setting up Phantom in the CS1000 (with script line: ROUTE CALL Phantomnumber) so a user can alter the destination via a remote callforward on his/her phone.

You can also setup some scripting and add dates to DATE variables like 'option1_Normal_Day' and 'Option1_to2_Day'.
If the user can change variables they just have to add a data range to the variable to alter the destination.

For the second option scripting could look like;

IF DATE = Option1_Normal_Day THEN
EXECUTE Option1_Normal_Routing
ENDIF
IF DATE = Option1_to2_Day THEN
EXECUTE Option1_To2_Routing
ENDIF

SECTION Option1_Normal_Routing
/* Normal routing for option 1 here */

SECTION Option1_To2_Routing
/* Re routing section */

 

[Supernn]

We've setup the following:

/******* Telephony *******/
SECTION MENU_2NDLINE
READVAR ICT_Telecom_WILDVAR
SAVEVAR
OPEN VOICE SESSION
IF ICT_Telecom_WILDVAR = 1 THEN
PLAY PROMPT VOICE SEGMENT Ann_Agent1
ELSE
PLAY PROMPT VOICE SEGMENT Ann_Agent2
END IF
PLAY PROMPT VOICE SEGMENT ICT_T_Change
COLLECT 1 DIGITS INTO Service_Choice
INTER DIGIT TIMER 3
END VOICE SESSION
READVAR ICT_Telecom_WILDVAR
IF Service_Choice = 1 THEN
ASSIGN 1 TO ICT_Telecom_WILDVAR
ELSE
ASSIGN 2 TO ICT_Telecom_WILDVAR
END IF
SAVEVAR
READVAR ICT_Telecom_WILDVAR
SAVEVAR
OPEN VOICE SESSION
IF ICT_Telecom_WILDVAR = 1 THEN
PLAY PROMPT VOICE SEGMENT Ann_Agent1
ELSE
PLAY PROMPT VOICE SEGMENT Ann_Agent2
END IF
PLAY PROMPT VOICE SEGMENT RETURN_TO_MAIN
COLLECT 1 DIGITS INTO Lang_Choice
INTER DIGIT TIMER 3
END VOICE SESSION
IF Lang_Choice = 9 THEN EXECUTE MENU_2NDLINE ELSE DISCONNECT END IF
END IF

This script alows you to switch by calling a script.
The other script merey uses the wildvars:
WHERE DNIS EQUALS
VALUE 1234 : READVAR ICT_Telecom_WILDVAR
SAVEVAR
OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT ICT_TELECOM_Welc
END VOICE SESSION
IF ICT_Telecom_WILDVAR = 1 THEN
ROUTE CALL ICT_Cell_Agent1
ELSE
ROUTE CALL ICT_Cell_Agent2
END IF
....
END WHERE

 

[Tman45]

Cool thank you both very much! We configured something similiar to this and added it on to our IT Help Desk. I really appreciate your responses. Stars for both

 

[mte0910]

One more way to skin the cat...

We use HDX to store who the last called technician was and and what day they were called, if the date is new, then the application moves on to the next tech, but if the date is the same, then the technician stays the same.

/**** START HEADER
Title: CTI_SUPPORT
Description: Cycles through CTI Technicians Various Phones.
Toll Free...(800) 123-4567
DNIS........5000
DID.........(901) 555-5000
CDN.........5000
DFDN........3000
END HEADER ****/


/**** HDX LOOKUP TECH AND DATE ****/
/*SECTION sec_one*/
ASSIGN 2 TO x_SQL_Statement_cv
SEND REQUEST x_Provider_ID2_gv x_SQL_Statement_cv
GET RESPONSE x_Provider_ID2_gv x_SQL_Result_cv, b_INT_01_cv


IF
x_SQL_Result_cv = "FAILED"
THEN
EXECUTE sec_three
END IF


IF
x_SQL_Result_cv = "NODATA"
THEN
EXECUTE sec_two
ELSE
EXECUTE sec_three
END IF



/**** CHANGE TECH AND DATE ****/
SECTION sec_two
ASSIGN 5 TO x_SQL_Statement_cv
SEND REQUEST x_Provider_ID2_gv x_SQL_Statement_cv
GET RESPONSE x_Provider_ID2_gv x_SQL_Result_cv, b_INT_01_cv


WHERE b_INT_01_cv EQUALS
VALUE 1: ASSIGN 2 TO b_INT_01_cv
VALUE 2: ASSIGN 3 TO b_INT_01_cv
VALUE 3: ASSIGN 1 TO b_INT_01_cv
DEFAULT: ASSIGN 1 TO b_INT_01_cv
END WHERE

ASSIGN 4 TO x_SQL_Statement_cv
SEND INFO x_Provider_ID2_gv x_SQL_Statement_cv, b_INT_01_cv



/**** CALL TECH OF THE DAY ****/
SECTION sec_three
WHERE b_INT_01_cv EQUALS
VALUE 1: ROUTE CALL 919015559000 /* Steve */
VALUE 2: ROUTE CALL 919015558000 /* Tom */
VALUE 3: ROUTE CALL 919015557000 /* Fred */
DEFAULT: ROUTE CALL 919015556000 /* Steve */
END WHERE