adding a bowse button to a form 8

WaltLukeIII · Jul 5, 2000

I have a form that imports an excel spreadsheet and I want to add a browse Button to the form does anyone know how to do this

jimmythegeek · Jul 5, 2000

I am assuming you mean an Open dialog box. 1) On your form, add a common dialog control (Insert ¦ ActiveX Control) (Microsoft common dialog control, version 5) 2) Name the control "cdlgOpen" 3) Add a button 4) Name the button "cmdBrowse" 5) Copy and paste the following code on the Click Event of the button (minus the Private & End Sub lines). ----- Private Sub cmdBrowse_Click()     Dim strFile As String     With Me.cdlgOpen         .CancelError = True         .Filter = "Excel Files (*.xls)¦*.xls¦"         .ShowOpen         strFile = .filename     End With End Sub ----- 6) Now your variable strFile will represent your file and you can do with it as you wish from that point. HTH Jim Lunde <a href=mailto:compugeeks@hotmail.com>compugeeks@hotmail.com</a> <a href=

http://www.cgeek.com>CompuGEEKS</a> Custom

Application Development

WaltLukeIII · Jul 5, 2000

I can't find an activex control I went under the insert menu and got a Custom Control and that brought up a window in which there where several choices. it had activeX Object but wouldn't let me do that saying that I was not registered. I am not sure if that is a version problem of what. Thanks for the help so far. Walt III

elizabeth · Jul 5, 2000

Jim, I'll find this useful too. Could you demo how to add a default path and filename stub? For example I'd like mine to defualt to: \\xxx\yy$\zzz*.xls would it be strFile = \\xxx\yy$\zzz*.xls or do I have to create some kind of default setting to see what's out there? Thanks

elizabeth · Jul 5, 2000

Walt, click on the "More Controls" (hammer) icon on your toolbar, then click on "Microsoft Common Dialog Control (in Access 2000 I have version 6.0).

WaltLukeIII · Jul 5, 2000

I can not find a "more controls"(hamme) on my toolbar. I found a hammer and wrench but that is for the "form design" toolbar. I don't know if it matters but I am using an updated version of office 97. But I don't think that that should matter.

elizabeth · Jul 5, 2000

Walt, it's on your Toolbox's toolbar. Jim, I'm monkeying around with the common dialog control's InitDir and FileName properties. My path is long, more like \\aaa-bb\ccy$\eeeeee\ffffffff\gggggg\ZZZyyyymmdd*.xls The FileName seems to work fine, but of the path only \\aaa-bb\ccy$ displays. there doesn't seem to be any Help on this to tell me if there is a character string limit.

WaltLukeIII · Jul 5, 2000

I do not have that option on this version. I have looked on another version and found it do you know of a back door way to get to the "Microsoft Command Diolag Control".

WaltLukeIII · Jul 5, 2000

What version of access are the two of you using?

elizabeth · Jul 5, 2000

I'm using Access 2000. Please ignore my previous question, the InitDir wasn't working simply because I miskeyed one of the folder names, so the control only displayed the portion that was valid.

jimmythegeek · Jul 5, 2000

Elizabeth, try the following: ---------- Private Const EXISTINGFILE As String = "C:\My Documents\Zips\tasks.xls" Private Sub cmdBrowse_Click()     Dim strNewFile As String          On Error GoTo Browse_Err     With Me.cdlgOpen         .filename = EXISTINGFILE         .CancelError = True         .Filter = "Excel Files (*.xls)¦*.xls¦"         .ShowOpen         strNewFile = .filename     End With      Browse_Exit:     Exit Sub Browse_Err:     If Err.Number = 32755 Then         Resume Browse_Exit     Else         MsgBox Err.Number & ": " & Err.Description         Resume Browse_Exit     End If End Sub ----- You can put the path (EXISTINGFILE) in a table, as a public constant, or even in an .ini file. Let me know if that works, or doesn't BTW: I am using Access 97 HTH Jim Lunde <a href=mailto:compugeeks@hotmail.com>compugeeks@hotmail.com</a> <a href=

http://www.cgeek.com>CompuGEEKS</a> Custom

Application Development

WaltLukeIII · Jul 5, 2000

I have managed to find the activeX control but there is no microsoft common dialog control are you using a developer edition of access? if So is there another way to get what I want? Thanks for the excellent help. Walt III

jimmythegeek · Jul 5, 2000

Do you have the following file? C:\Windows\System\Comdlg32.ocx If you don't, then find it on somebody's system and copy it there, then continue. If you do have it, then: Go to the design of your form Go to the code window (View ¦ Code) Go to Tools ¦ ActiveX Controls Select Register Find the .ocx above Select it, and hit Open Now you should be able to insert it on your form by going to Insert ¦ ActiveX Control Jim Lunde <a href=mailto:compugeeks@hotmail.com>compugeeks@hotmail.com</a> <a href=

http://www.cgeek.com>CompuGEEKS</a> Custom

Application Development

WaltLukeIII · Jul 6, 2000

It now tells me that I do not have the liscense required to insert this object. Your Persistent help has been most appreciated.

elizabeth · Jul 6, 2000

Jim, what's that error number 32755 that we're ignoring?

hcsd · Jul 6, 2000

Hi Jim, I was trying to do something similar to this when I ran across this discussion. Maybe you can help with what I am trying to do. I have added the browse button to my program per your intructions and the open dialog works just fine.  Although, I only need to browse for a directory not a filename. How would I get just the directory name?

elizabeth · Jul 6, 2000

FYI, InitDir is a property of the control. If you key it into the property area, the control will display all files in that directory. If you wanted to you could set that property in code instead I imagine.

jimmythegeek · Jul 6, 2000

Elizabeth, The error is: "Cancel was selected" If the user selects the cancel button, you get that error. I thought the .CanclError = True was supposed to handle this, but it doesn't seem to, so that's why I added the err trap. ===== hcsd Elizabeth was right, instead of using .Filename, use .InitDir instead. This will default to the directory you specify. You can hard code it, use a variable, constant, value from a table, or a value in an .ini file, whatever you prefer. ===== Walt, I am not quite sure why you are having so much trouble. What version of Access are you using? The .ocx file may be too old, or too new for the version you are using. If you continue to have trouble, try the Microsoft knowledge base, or try to contact Microsoft regarding the license issue. ===== All, Let me expound on the point of where to store the path. I am a big fan of NOT hard coding anything that has a possiblity of changing. So I either put my values in a table called tblSettings: Key                Setting ----------------------------------------------------------------------- ImportPath        "C:\My Documents\" ExportPath       "\\Prod1\Data\Access\Project1\" I then use a DLookUp in the code to get the value:  .FileName = DLookUp("Setting", "tblSettings", "Key = 'ImportPath'&quot

. This allows me to change the path anytime I wish without having to adjust code. This is crucial for us, because every time we touch code, we have to re-compact, re-compile, make a new .mde, and roll it out. If it's in a table, I can change the value, and never worry about anything else. The other option is to use an .ini File. This is just as effective. I use a function Called GetINI to return the value. This allows me to change the .ini file and never have to touch the database at all. Hope this helps. Jim Lunde <a href=mailto:compugeeks@hotmail.com>compugeeks@hotmail.com</a> <a href=

http://www.cgeek.com>CompuGEEKS</a> Custom

Application Development

mesavage · Jul 3, 2002

I know this thread is old, but I am having the same problem as Walt (i.e. the licensing problem). I have no idea what the problem is, and can not seem to find an answer on the microsoft knowledge base. Does anyone know what the deal is? I have Access 2000. Is there something special needed to use this particular control? Thanks.

oharab · Jul 3, 2002

Instead of using an activex control, I always use this:

'***************** Code Start **************
'This code was originally written by Ken Getz.
'It is not to be altered or distributed,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
' Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996

Type tagOPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal FileName As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal Hwnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant

' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFilename As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.
If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(filter) Then filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(FileName) Then FileName = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(Hwnd) Then Hwnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFilename = Left(FileName & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With OFN
.lStructSize = Len(OFN)
.hwndOwner = Hwnd
.strFilter = filter
.nFilterIndex = FilterIndex
.strFile = strFilename
.nMaxFile = Len(strFilename)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
.strCustomFilter = ""
.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With

' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(OFN)
Else
fResult = aht_apiGetSaveFileName(OFN)
End If

' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = OFN.Flags
ahtCommonFileOpenSave = TrimNull(OFN.strFile)
Else
ahtCommonFileOpenSave = "NoFile"
End If
End Function

Function ahtAddFilterItem(strFilter As String, _
strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases&quot

, a null character, the skeleton
' (like "*.mdb;*.mda&quot

and a final null character.

If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & _
strDescription & vbNullChar & _
varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
intPos = InStr(strItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(strItem, intPos - 1)
Else
TrimNull = strItem
End If
End Function
'************** Code End *****************
Call it like this:

Function TestIt()
Dim strFilter As String
Dim lngFlags As Long
strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda, *.mdb)", _
"*.MDA;*.MDB&quot

strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF&quot

strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT&quot

strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*&quot

MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\", _
filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
DialogTitle:="Hello! Open Me!&quot

' Since you passed in a variable for lngFlags,
' the function places the output flags value in the variable.
End Function

HTH

Ben ----------------------------------
Ben O'Hara
bo104@westyorkshire.pnn.police.uk
----------------------------------

Tek-Tips is the largest IT community on the Internet today!

Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!

adding a bowse button to a form 8

Programmer

Programmer

Programmer

IS-IT--Management

IS-IT--Management

Programmer

IS-IT--Management

Programmer

Programmer

IS-IT--Management

Programmer

Programmer

Programmer

Programmer

IS-IT--Management

Programmer

IS-IT--Management

Programmer

Programmer

Programmer

Similar threads

Log in

Part and Inventory Search

Sponsor