Access tablet battery status 2

[AlastairP]

I have a VP9 application running on a windows tablet that runs full screen including hiding the task bar.
I would like to access the battery life information so I can display the info in the application.

Anyone know how that can be done?

Alastair

 

[atlopes]

Alastair,

Check the Win32_Battery class at

https://docs.microsoft.com/en-us/windows/desktop/cimwin32prov/win32-battery.

A sample usage:

CLEAR

LOCAL BStatus AS String

TEXT TO m.BStatus NOSHOW
:1:Discharging:
:2:Connected to AC:
:3:Fully charged:
:4:Low:
:5:Critical:
:6:Charging:
:7:Charging and high:
:8:Charging and low:
:9:Charging and critical:
:10:Undefined:
:11:Partially charged:
ENDTEXT

LOCAL WMIService, AllBatteries, Battery

m.WMIService = GETOBJECT("winmgmts:\\.\root\cimv2")

m.AllBatteries = m.WMIService.ExecQuery("SELECT * FROM Win32_Battery",,48)

FOR EACH m.Battery IN m.AllBatteries

	? "Battery status:", STREXTRACT(m.BStatus, TEXTMERGE(":<<m.Battery.BatteryStatus>>:"), ":")
	? "Charged at", TRANSFORM(m.Battery.EstimatedChargeRemaining), "%"

ENDFOR

 

[AlastairP]

Thanks! I will take a look at this.