How to keep multiple versions(999+) of your source files ?

@echo off
rem -----------------------------------------------------
rem This batch file will rename files of the order
rem abcd.102 to abcd.103
rem abcd.101 to abcd.102
rem and frees the first slot for a newer file.
rem This utility batch can be used for keeping last upto 899 files,
rem for backup(old versions). It may be helpful in case the class, or other files
rem get corrupted and requires a backup. 
rem Uses pkzip.exe. You can use any other zip/report program which generate a single file
rem that requires last finite number of versions(999,9999, ...)
rem
rem No (c) copyright of any kind.
rem Nasib Kalsi 2007-12-02
rem 
rem Handle files of the order abcd.199, abcd.198,  ... abcd.101
rem
echo .
echo . Working, please wait
echo .

rem --------------------------------------------------
rem Modify the following parameters as per your requirements
rem No spaces around = sign
set SourceFiles=p:\uw\inv\*.*
set BakDir=c:\Bak123
set FileName=abcd

set/a RootFileExt  = 100
set/a FirstFileExt = RootFileExt + 1
set/a LastFileExt  = 199

rem --------------------------------------------------

rem Make BackupDir
if exist %BakDir%\%FileName%.%FirstFileExt% goto Begin
md %BakDir%

:Begin
   set /a LastFileExt = LastFileExt - 1
   if %LastFileExt%==%RootFileExt% goto End
   if exist %BakDir%\%FileName%.%LastFileExt% goto Yes
   goto Begin

:Yes
   set /a j = LastFileExt + 1
   ren %BakDir%\%FileName%.%LastFileExt% %FileName%.%j%
   goto Begin

:End


:ZipNow
rem Now create a zip/report file in slot 101 (abcd.101)
pkzip %BakDir%\%FileName%.%FirstFileExt% %SourceFiles%

echo .
echo . Done
echo .